Для измерения действительной емкости был собран простейший стенд на основе Arduino Nano. Сначала я полностью заряжал батарею (в телефоне), а потом подключал к батарею к стенду, где она разряжалась через резистор 14.4 ома (6 последовательно включенных резистора сопротивлением 2.4 ом каждый). Ниже приведена схема стенда и его модель, созданные в системе проектирования Fritzing [1].

А вот так стенд выглядит в собранном виде:

Принцип измерения емкости аккумулятора прост. Последовательно включенные резисторы R2..R6 и R7 работают не только как нагрузка для аккумулятора, но и еще как делитель напряжения 1/6. С резистора R7 снимается напряжение и подается на канал АЦП A0 платы Arduino. Поскольку напряжение на аккумуляторе меняется в пределах от 4.2 до 2.5 вольт, то на вход АЦП приходит напряжение от 0.7 до 0.41 вольта, поэтому АЦП переключено на внутренний источник опорного напряжения 1.1V. Напряжение на батарее в вольтах вычисляется по формуле:

U = (6 * (1.1 * adcraw)) / 1024;

где adcraw это значение, считанное из регистров АЦП. Ток через батарею в амперах вычисляется по формуле:

I = (U / 6) / 2.4;

Емкость батареи в ампер/часах считается как накапливаемый с каждой секундой интеграл, пока батарея не разрядится полностью. Т. е. при запуске разряда счетчик емкости батареи обнуляется, и каждую секунду к нему прибавляется текущее значение тока через батарею в амперах, поделенное на 3600 секунд (в часу 60 минут, в минуте 60 секунд, итого в часе 3600 секунд). В момент окончания разряда в счетчике оказывается емкость батареи.

Начало заряда определяется по подключению батареи (скачку тока от нуля до значения выше 50 мА), а окончание заряда по срабатыванию защиты от перезаряда [2] (при этом ток через батарею падает до нуля).

Светодиод используется только для индикации процесса работы скетча. В режиме ожидания подключения батареи он дает короткие ежесекундные вспышки, а когда батарея подключена и начинает разряжаться, то скважность мигания меняется на равномерную (время включения светодиода равно времени выключения и равно 500 мс).

/*

  Программа-скетч, которая измеряет время полного разряда аккумулятора.

  Использовалась для тестирования аккумуляторов смартфона Samsung Galaxy

  GT-N7000. Аккумулятор разряжался током порядка 250 мА (через резистор

  14.4 Ом, состоящий из цепочки 6 резисторов по 2.4 Ом) из полностью

  заряженного состояния до полностью разряженного.

 
           2.4       2.4      2.4      2.4      2.4      2.4

  GND ----[   ]--x--[   ]----[   ]----[   ]----[   ]----[   ]----< --- 3.7V

                 |

                ADC 

  Начало заряда определялось по возрастанию напряжения на части резистора

  нагрузки.

  Окончание разряда определялось по пропаданию напряжения на этом же

  резисторе, потому что при полном разряде в аккумуляторе срабатывала

  встроенная защита от переразряда.

*/
 

//Счетчик секунд с момента начала разряда

unsigned long seconds;

//Напряжение, ток, емкость батареи.

float U, I, capacity;
 

void setup()
{
  pinMode(13, OUTPUT);
  Serial.begin(9600);
  analogReference(INTERNAL);  //опорное напряжение для ADC 1.1V
  Serial.print("[Программа тестирования емкости Li-Ion аккумулятора]");
}
 

//Подпрограмма считывает АЦП и по его значению вычисляет:

// U напряжение батареи

// I ток батареи

void readUI (void)
{
  int adcraw;
 
  adcraw = analogRead(A0);
  // У нас 6 последовательно соединенных резисторов, и arcraw
  // считывается с одного из них. Опорное 1.1V, ему соответствует
  // 1024 отсчета.
  U = (6 * (1.1 * adcraw)) / 1024;
  // Ток вычисляется по закону Ома: I = U / R
  I = (U / 6) / 2.4;
}
 

void loop()
{
  Serial.print("\r\nПодключите батарею...");
  //Ждем подключения батареи (начала разряда):
  do
  {
    digitalWrite(13, HIGH);
    delay(100);
    digitalWrite(13, LOW);
    delay(900);
    readUI();
  }
  while (I < 0.05);
  Serial.println("\r\nРазряд начался");
  //Ждем окончания разряда:
  seconds = 0;
  capacity = 0;
  while(true)
  {
    digitalWrite(13, HIGH);
    delay(500);
    digitalWrite(13, LOW);
    delay(500);
    seconds++;
    readUI();
    capacity += (I / 3600);
    if (I < 0.05)
    {
      Serial.print("\r\nI < 0.05A");
      break;
    }
    if (U < 2.5)
    {
      Serial.print("\r\nU < 2.5V");
      break;
    }
    Serial.print("\rПрошло ");
    Serial.print(seconds, DEC);
    Serial.print(" секунд, U=");
    Serial.print(U, 2);
    Serial.print("V I=");
    Serial.print(I, 3);
    Serial.print("A емкость=");
    Serial.print(capacity, 4);
    Serial.print("A/ч");
  }
  Serial.print("\r\nБатарея разряжена");
}

Пример вывода программы в консоль:

На стенде батарейка разряжается практически в "ноль", потому что уровень разряда ограничен только защитой в контроллере батареи. В реальных условиях эксплуатации (в телефоне, смартфоне) обычно максимально возможная глубина разряда батареи меньше на 15..25%.

Это самый натуральный фейк, несмотря на солидность упаковки и даже наличие наклеенной голограммы. Заявленная емкость 2500 мА/ч, а реальная измеренная всего лишь 608 мА/ч. Короче говоря, эта батарейка работала еще хуже, чем моя старая, которую я собрался менять, её едва-едва хватало на полдня работы.

Внешне батарейка выглядела совсем как оригинальная, так что заподозрить обман довольно трудно. Для того, чтобы заметить проблемы, нужно её установить в телефон и внимательно приглядеться к корпусу. Во-первых, в отличие от оригинальной батареи Samsung, на корпусе этой подделки нет даты изготовления батареи. На упаковке Вы также не найдете даты изготовления - признак, что батарея явный фейк. Во-вторых, корпус батареи имеет вмятины. Обратите внимание - это хорошо видно на фото ниже. В-третьих, размер корпуса батареи оказался короче на миллиметр, чем стандартный. Мне пришлось вырезать из пластиковой карты вкладыш, чтобы батарея не вываливалась и надежно прилегала к контактам:

Когда я разобрал батарею, то стало понятно, откуда вмятины, и отчасти стала ясна причина малой емкости.

Как Вы видите, энергоноситель имеет уменьшенные габариты. Заводская маркировка энергоячейки совершенно невнятная, нет ни емкости, ни даты изготовления.

Все пустое пространство залито эластичной пластмассой, похожей на твердую резину. Этим объясняются вмятины на корпусе. Маленькая банка никак не может давать полной заявленной емкости, и скорее всего это просто некондиция - отбраковка производства.

К сожалению, контроллер тоже был залит пластиком, и я не сразу понял, что его можно легко отслоить феном. Поэтому плату контроллера по неопытности я полностью разломал. Там была применена микросхема контроллера защиты Li-Ion батарей S-8205A/B [3]. Кстати, контроллер был очень похож на контроллер батареи Tiger Energy (см. далее).

Такую батарейку точно покупать не стоит!

Емкость ниже заявленной, но что Вы хотели за 400 рублей? Получайте 2070 мА/ч вместо 2500 мА/ч:

Tiger Energy пытается почему-то во всем подражать Infinity, но упаковка у Infinity выглядит более качественно. За эту батарейку часто просят 500 рублей, но можно сторговаться и за 400.

На батарейке написано 2700 мА/ч, но на самом деле вытягивает она только 2037 мА/ч.

Под желтой наклейкой скрывается батарея с заводской маркировкой 2500 мА/ч. На маркировке также проставлена дата изготовления ячейки (январь 2014 года). Возможно, батарея потеряла часть своей емкости из-за долгого хранения на складе, но все равно она никак не может быть на 2700 мА/ч просто физически:

Контроллер KLX-PACi9000 был по китайской традиции залит черным эластичным пластиком, но мне удалось его удачно отслоить с помощью фена:

На плате контроллера хорошо видна микросхема защиты Li-Ion батарей FS8205A [3].

Упаковка качественная, на отделку и голограммы не поскупились. На рынке её рекламировали как самый лучший вариант ("долго держит!").

К сожалению, даты изготовления не упаковке и копусе батареи я не нашел.

После испытаний оказалось, что реальная емкость 2417 мА/ч почти совпадает с заявленной 2550 мА/ч. Это самая лучшая батарея из всех, что я протестировал.

Вполне достойная по качеству и цене батарейка.